對(duì)于復(fù)雜的計(jì)算，單片機(jī)的速度顯得偏慢。最好的辦法是由人工事先算出全部的結(jié)果，依次存放在ROM中，程序執(zhí)行時(shí)，直接從ROM中查出結(jié)果即可。

51單片機(jī)有兩條查表指令：

MOVC A, @A + PC
MOVC A, @A + DPTR

前一條可以不用 DPTR，但是其中有個(gè)“偏移量”頗為難算，因?yàn)樯婕暗街噶钭止?jié)數(shù)的基本概念、查表等，令很多人頭痛。
做而論道針對(duì)這個(gè)問(wèn)題，研究出一個(gè)自動(dòng)計(jì)算偏移量的方法，可以避免煩瑣的人工計(jì)算過(guò)程。

下面是做而論道回答的一個(gè)網(wǎng)上的題目：

在 30H ~ 39H中，預(yù)先存入數(shù)據(jù)為 1，3，5，7，9，2，4，6，8，10。
利用 MOVC A, @A + PC 指令編寫(xiě)一查平方表程序，將片內(nèi)30H ~ 39H內(nèi)的數(shù)求出平方后送入40H ~ 49H單元。

做而論道編寫(xiě)的程序如下：
;-------------------------------------------
org 0000h

mov 30h, #1 ;先存放一些數(shù)據(jù)
mov 31h, #3
mov 32h, #5
mov 33h, #7
mov 34h, #9
mov 35h, #2
mov 36h, #4
mov 37h, #6
mov 38h, #8
mov 39h, #10

call SQRT ;調(diào)用子程序，求出上述10個(gè)數(shù)字的平方
;存放在40H開(kāi)始的單元部分略
sjmp $
;-------------------------------------------
;用查表法求平方的子程序
SQRT:
MOV R0, #30H ;源數(shù)值起始地址
MOV R1, #40H ;目標(biāo)起始地址
MOV R2, #10 ;共有10個(gè)數(shù)字
LOOP:
MOV A, @R0
ADD A, #S_TAB - ($ + 3) ;自動(dòng)計(jì)算偏移量
MOVC A, @A + PC ;查表，求出平方
MOV @R1, A
INC R0
INC R1
DJNZ R2, LOOP
RET
;-------------------
S_TAB:
DB 0, 1, 4, 9, 16, 25, 36, 49, 64, 81, 100, 121, 144, 169, 196
;-------------------------------------------
;完

提問(wèn)者對(duì)于答案的評(píng)價(jià)：恩恩 很對(duì)的 不過(guò) #S_TAB - ($ + 3)這個(gè)什么意思?。?/p>

========================================

算法說(shuō)明：

在 S_TAB 開(kāi)始，用 DB 偽指令存放了一系列的《平方數(shù)字》。－－百度排版很差，引號(hào)，顯示的太小，用書(shū)名號(hào)代替。

那么，從S_TAB 開(kāi)始數(shù)，第 0 個(gè)字節(jié)，就是 0 的平方，第 1 個(gè)字節(jié)，就是 1 的平方，……，第 14 個(gè)字節(jié)，就是 14 的平方。

如果，查表指令MOVC A, @A + PC 中的 PC 等于S_TAB 就好了，A 是幾，就能從表中，查出幾的平方。

呵呵，這有點(diǎn)像《立定跳遠(yuǎn)》，站在跳板上，有多大的勁，就跳多遠(yuǎn)。

而實(shí)際上，執(zhí)行查表指令MOVC A, @A + PC 時(shí)，PC，它并不等于S_TAB。

怎么辦 ？想想跳遠(yuǎn)就知道，加上助跑，就可以了。助跑的步數(shù)或米數(shù)，大家應(yīng)該都會(huì)算。

在執(zhí)行查表指令之前，把S_TAB 和執(zhí)行查表指令時(shí)的 PC 之差，算出來(lái)，加入到 A 中，即可。

這個(gè)數(shù)字，稱為偏移量，加入到 A 中，這就相當(dāng)于《助跑》。

計(jì)算這個(gè)偏移量，就是要統(tǒng)計(jì)S_TAB 和執(zhí)行查表指令時(shí)的 PC 之間的字節(jié)數(shù)。

如果不熟悉機(jī)器語(yǔ)言，由人工計(jì)算偏移量，是相當(dāng)難的。

而且，如果修改了這其中的指令，還要重新計(jì)算，非常的麻煩。

幸好，做而論道發(fā)明了自動(dòng)計(jì)算偏移量的方法。

程序中，下面的兩行：

ADD A, #S_TAB - ($ + 3) ;2字節(jié)
MOVC A, @A + PC ;1字節(jié)

即完成了自動(dòng)計(jì)算偏移量、查表的工作。

程序中的算式為：#S_TAB - ($ + 3)，也可以寫(xiě)成：#S_TAB - $ - 3。

下面是各個(gè)部分說(shuō)明：

$：代表 ADD 指令所在的當(dāng)前地址；

$ + 3：即執(zhí)行查表指令時(shí)的 PC 數(shù)值，加 3，是這兩條指令共占用了三個(gè)字節(jié)；

S_TAB - ($ + 3)：求出表格首地址與查表時(shí)地址的差值；

按照單片機(jī)教材上介紹的方法，使用 MOVC A, @A + PC 指令，是要人工計(jì)算《查表指令與表首之間地址的差值》的。

用過(guò)這種方法的人，都知道有多難。

所以，絕大多數(shù)人，都寧可浪費(fèi)一個(gè) DPTR，也不愿意計(jì)算這個(gè)差值。

而做而論道研究出來(lái)的這個(gè)公式，有理論，有實(shí)踐方法，極大的方便了單片機(jī)編程人員，值得廣泛推廣。