小愛同學(xué)吃灰很久了，一直想接入小愛來控制些智能硬件，無奈小米的IOT開放平臺(tái)只對(duì)企業(yè)用戶開放。最近研究了點(diǎn)燈科技的物聯(lián)網(wǎng)平臺(tái)，軟件硬件支持非常豐富，關(guān)鍵對(duì)于愛好者有免費(fèi)的版本可以使用，愛了愛了有木有？本篇分享下如何通過Blinker平臺(tái)接入小愛同學(xué)，進(jìn)而控制聯(lián)網(wǎng)的ESP8266點(diǎn)燈。

我使用了如下圖所示ESP8266開發(fā)板，其實(shí)就是板載了8266最小系統(tǒng)和USB轉(zhuǎn)串口部分。淘寶上很多，大的區(qū)別可能就是串口芯片有CH340和CP2102之分吧。

ESP8266模塊板載了LED燈，連接在GPIO2上，GPIO2輸出高電平燈熄滅，輸出低電平燈點(diǎn)亮，就拿它做控制吧。

在小愛同學(xué)APP中智能家居設(shè)備需要從米家APP中添加。所以，這兩個(gè)APP提前下載注冊(cè)好。這里重點(diǎn)說下Blinker APP。

• 從官網(wǎng)下載Blinker，支持安卓和蘋果版本，選擇你喜歡的對(duì)應(yīng)下載，并進(jìn)行注冊(cè)(https://www.diandeng.tech/doc/app-download)。

• 點(diǎn)擊添加設(shè)備，選擇Diy設(shè)備中的Arduino，選擇WiFi接入。會(huì)得到唯一的密鑰，這個(gè)很重要，后面需要在代碼中添加。

• 返回設(shè)備列表頁，點(diǎn)擊添加的設(shè)備圖標(biāo)進(jìn)入設(shè)備控制面板。可點(diǎn)擊右上角進(jìn)行編輯，這里的設(shè)備名最好用中文，后面用小愛進(jìn)行控制的時(shí)候，你對(duì)它說英文，它可能聽不懂哈。

1. 安裝ESP8266開發(fā)板擴(kuò)展

• 啟動(dòng)Arduino IDE，單擊「文件」—「首選項(xiàng)」，在附加開發(fā)板管理網(wǎng)址中輸入如下網(wǎng)址：

http://arduino.esp8266.com/stable/package_esp8266com_index.json

• 單擊「工具」—「開發(fā)板」—「開發(fā)板管理器」，在搜索欄輸入"esp8266"，找到開發(fā)板進(jìn)行安裝，如下圖安裝完成。

這個(gè)過程如果你網(wǎng)絡(luò)不夠科學(xué)的話，可能無法完成，官方提供了離線安裝方式可參照安裝(https://www.arduino.cn/thread-76029-1-1.html)。

2. 安裝blinker Arduino庫

下載庫(https://github.com/blinker-iot/blinker-library/archive/master.zip)，將下載好的blinker庫解壓到 我的電腦>文檔>Arduino>libraries 文件夾中。

3. 程序下載

Blinker官方提供了小愛同學(xué)的接入流程，以RGB燈的控制為例，介紹了小愛同學(xué)的各操作接口，具體可參照官方介紹(https://www.diandeng.tech/doc/xiaoai)。

我在這里做了簡(jiǎn)化，只用來控制燈的亮滅，只用了電源類操作接口和設(shè)備查詢接口。其實(shí)就是實(shí)現(xiàn)兩個(gè)回調(diào)函數(shù)，當(dāng)接收到小愛同學(xué)的命令，會(huì)對(duì)應(yīng)進(jìn)入回調(diào)函數(shù)去操作硬件。

代碼如下，代碼中的auth、ssid、pswd要填入實(shí)際的值。

#define BLINKER_WIFI
#define BLINKER_MIOT_LIGHT

#include <Blinker.h>

char auth[] = "Your Device Secret Key";
char ssid[] = "Your WiFi network SSID or name";
char pswd[] = "Your WiFi network WPA password or WEP key";

bool ledState;

void dataRead(const String & data)
{
  BLINKER_LOG("Blinker readString: ", data);

  uint32_t BlinkerTime = millis();

  Blinker.print("millis", BlinkerTime);
}

void miotPowerState(const String & state)
{
  BLINKER_LOG("need set power state: ", state);

  if (state == BLINKER_CMD_ON) {
    digitalWrite(LED_BUILTIN, LOW);
    BlinkerMIOT.powerState("on");
    BlinkerMIOT.print();
    ledState = true;
  }
  else if (state == BLINKER_CMD_OFF) {
    digitalWrite(LED_BUILTIN, HIGH);
    BlinkerMIOT.powerState("off");
    BlinkerMIOT.print();
    ledState = false;
  }
}

void miotQuery(int32_t queryCode)
{
  BLINKER_LOG("MIOT Query codes: ", queryCode);

  switch (queryCode)
  {
    case BLINKER_CMD_QUERY_POWERSTATE_NUMBER :
      BLINKER_LOG("MIOT Query Power State");
      BlinkerMIOT.powerState(ledState ? "on" : "off");
      BlinkerMIOT.print();
      break;

    default :
      BlinkerMIOT.powerState(ledState ? "on" : "off");
      BlinkerMIOT.print();
      break;
  }
}
void setup()
{
  Serial.begin(115200);
  BLINKER_DEBUG.stream(Serial);
  BLINKER_DEBUG.debugAll();

  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, HIGH);

  Blinker.begin(auth, ssid, pswd);

  Blinker.attachData(dataRead);
  BlinkerMIOT.attachPowerState(miotPowerState);
  BlinkerMIOT.attachQuery(miotQuery);
}

void loop()
{
  Blinker.run();
}

選擇開發(fā)板類型和實(shí)際端口號(hào)，進(jìn)行程序下載。

• 下載好程序后，復(fù)位開發(fā)板，然后在Blinker APP中會(huì)看到添加的設(shè)備已經(jīng)現(xiàn)在在線了。

• 進(jìn)入米家APP，點(diǎn)擊「我的」—「其他平臺(tái)設(shè)備」，添加點(diǎn)燈科技，進(jìn)入后，點(diǎn)擊同步設(shè)備，就會(huì)看到在Blinker中創(chuàng)建的設(shè)備。

• 前面綁定成功后，小愛同學(xué)中就會(huì)出現(xiàn)綁定的設(shè)備了。

試著對(duì)小愛說：“打開燈”、“關(guān)閉燈”、“燈的狀態(tài)”，可能網(wǎng)絡(luò)不好會(huì)有些延遲，不過想要的控制已經(jīng)實(shí)現(xiàn)了，放一下測(cè)試時(shí)拍的視頻，你也可以嘗試去控制些別的設(shè)備了。