;*********************************************************************/
T_CLK Bit P2.7 ;實(shí)時(shí)時(shí)鐘時(shí)鐘線引腳
T_IO Bit P1.4 ;實(shí)時(shí)時(shí)鐘數(shù)據(jù)線引腳
T_RST Bit P1.5 ;實(shí)時(shí)時(shí)鐘復(fù)位線引腳
;**********************************************************
;子程序名：Set1302
;功 能：設(shè)置DS1302 初始時(shí)間,并啟動(dòng)計(jì)時(shí)。
;說 明：
;調(diào) 用：RTInputByte
;入口參數(shù)：初始時(shí)間在:Second,Minute,Hour,Day,Month,Week.YearL(地址連續(xù))
;出口參數(shù)：無
;影響資源：A B R0 R1 R4 R7
;設(shè) 計(jì)：zhaojunjie 日 期：2002-03-19
;修 改： 日 期：
;**********************************************************
Set1302:
CLR T_RST
CLR T_CLK
SETB T_RST
MOV B, #8EH ;控制寄存器
LCALL RTInputByte
MOV B, #00H ;寫操作前WP=0
LCALL RTInputByte
SETB T_CLK
CLR T_RST

MOV R0, #Second;
MOV R7, #7 ;秒分 時(shí) 日 月 星期 年
MOV R1, #80H ;秒寫地址
S13021: CLR T_RST
CLR T_CLK
SETB T_RST
MOV B, R1 ;寫秒分 時(shí) 日 月 星期 年 地址
LCALL RTInputByte
MOV A, @R0 ;寫秒數(shù)據(jù)
MOV B, A
LCALL RTInputByte
INC R0
INC R1
INC R1
SETB T_CLK
CLR T_RST
DJNZ R7, S13021
CLR T_RST
CLR T_CLK
SETB T_RST
MOV B, #8EH ;控制寄存器
LCALL RTInputByte
MOV B, #80H ;控制,WP=1,寫保護(hù)
LCALL RTInputByte
SETB T_CLK
CLR T_RST
RET
;**********************************************************
;子程序名：Get1302
;功 能：從DS1302 讀時(shí)間
;說 明：
;調(diào) 用：RTInputByte,RTOutputByte
;肟誆問?菏奔潯４嬖?Second,Minute,Hour,Day,Month,Week.YearL
;出口參數(shù)：無
;影響資源：A B R0 R1 R4 R7
;設(shè) 計(jì)：zhaojunjie 日 期：2002-03-19
;修 改： 日 期：
;**********************************************************
Get1302:
MOV R0, #Second;
MOV R7, #7
MOV R1, #81H ;秒地址
G13021: CLR T_RST
CLR T_CLK
SETB T_RST
MOV B, R1 ;秒分 時(shí) 日 月 星期 年 地址
LCALL RTInputByte
LCALL RTOutputByte
MOV @R0, A ;秒
INC R0
INC R1
INC R1
SETB T_CLK
CLR T_RST
DJNZ R7, G13021
RET
;**********************************************************
;功 能：寫1302一字節(jié) （內(nèi)部子程序）
;**********************************************************
RTInputByte:
MOV R4, #8
Inbit1: MOV A, B
RRC A
MOV B, A
MOV T_IO, C
SETB T_CLK
CLR T_CLK
DJNZ R4, Inbit1
RET
;**********************************************************
;功 能：讀1302一字節(jié) （內(nèi)部子程序）
;**********************************************************
RTOutputByte:
MOV R4, #8
Outbit1: MOV C, T_IO
RRC A
SETB T_CLK
CLR T_CLK
DJNZ R4, Outbit1
RET