測速是工農業(yè)生產中經常遇到的問題，學會使用單片機技術設計測速儀表具有很重要的意義。

要測速，首先要解決是采樣的問題。在使用模擬技術制作測速表時，常用測速發(fā)電機的方法，即將測速發(fā)電機的轉軸與待測軸相連，測速發(fā)電機的電壓高低反映了轉速的高低。使用單片機進行測速，可以使用簡單的脈沖計數法。只要轉軸每旋轉一周，產生一個或固定的多個脈沖，并將脈沖送入單片機中進行計數，即可獲得轉速的信息。

一、脈沖信號的獲得

可以有多種方式來獲得脈沖信號，這些方法有各自的應用場合。下面逐一進行分析。

1．霍爾傳感器

圖1 CS3020引腳圖

霍爾傳感器是對磁敏感的傳感元件，常用于開關信號采集的有CS3020、CS3040等，這種傳感器是一個3端器件，外形與三極管相似，只要接上電源、地，即可工作，輸出通常是集電極開路（OC）門輸出，工作電壓范圍寬，使用非常方便。如圖1所示是CS3020的外形圖，將有字面對準自己，三根引腳從左向右分別是VCC、地、輸出。

使用霍爾傳感器獲得脈沖信號，其機械結構也可以做得較為簡單，只要在轉軸的圓周上粘上一粒磁鋼，讓霍爾開關靠近磁鋼，就有信號輸出，轉軸旋轉時，就會不斷地產生脈沖信號輸出。如果在圓周上粘上多粒磁鋼，可以實現(xiàn)旋轉一周，獲得多個脈沖輸出。在粘磁鋼時要注意，霍爾傳感器對磁場方向敏感，粘之前可以先手動接近一下傳感器，如果沒有信號輸出，可以換一個方向再試。

這種傳感器不怕灰塵、油污，在工業(yè)現(xiàn)場應用廣泛。

2．光電傳感器

光電傳感器是應用非常廣泛的一種器件，有各種各樣的形式，如透射式、反射式等，基本的原理就是當發(fā)射管光照射到接收管時，接收管導通，反之關斷。以透射式為例，如圖2所示，當不透光的物體擋住發(fā)射與接收之間的間隙時，開關管關斷，否則打開。為此，可以制作一個遮光葉片如圖3所示，安裝在轉軸上，當扇葉經過時，產生脈沖信號。當葉片數較多時，旋轉一周可以獲得多個脈沖信號。

圖2 光電傳感器的原理圖

圖3 遮光葉片

3．光電編碼器

光電編碼器的工作原理與光電傳感器一樣，不過它已將光電傳感器、電子電路、碼盤等做成一個整體，只要用連軸器將光電傳感器的軸與轉軸相連，就能獲得多種輸出信號。它廣泛應用于數控機床、回轉臺、伺服傳動、機器人、雷達、軍事目標測定等需要檢測角度的裝置和設備中。如圖4所示，是某光電編碼器的外形。

圖4 成品光電編碼器

二、硬件連接

測速的方法決定了測速信號的硬件連接，測速實際上就是測頻，因此，頻率測量的一些原則同樣適用于測速。

通常，可以用計數法、測脈寬法和等精度法來進行測試。所謂計數法，就是給定一個閘門時間，在閘門時間內計數輸入的脈沖個數；測脈寬法是利用待測信號的脈寬來控制計數門，對一個高精度的高頻計數信號進行計數。由于閘門與被測信號不能同步，因此，這兩種方法都存在±1誤差的問題，第一種方法適用于信號頻率高時使用，第二種方法則在信號頻率低時使用。等精度法則對高、低頻信號都有很好的適應性。

這里為簡化討論，僅采用計數法來進行測試。

圖5所示是測速器的電路圖，由六位數碼管和測速接口組成。其中T0處接的只畫了一只CS3020組成的霍爾傳感器接線圖，如果采用光電傳感器接口也是一樣的，讀者可自行畫出接線圖。

圖5 測速計電路原理圖

三、軟件編程

　　測量轉速，使用霍爾傳感器，被測軸安裝有12只磁鋼，即轉軸每轉一周，產生12個脈沖，要求將轉速值（轉/分）顯示在數碼管上。

　　程序如下：

　　DISPBUF EQU 5AH ;顯示緩沖區(qū)從5AH開始

　　SecCoun EQU 59H

　　SpCoun EQU 57H ;速度計時器單元57H和58H，高位在前（57H單元中）

　　Count EQU 56H ;顯示時的計數器

　　SpCalc bit 00h ;要求計算速度的標志

　　Hidden EQU 16 ;消隱碼

　　ORG 0000H

　　AJMP START

　　ORG 1BH

　　JMP TIMER1 ;定時中斷1入口

　　ORG 30H

　　START: MOV SP,#5FH ;設置堆棧

　　MOV P1,#0FFH

　　MOV P0,#0FFH

　　MOV P2,#0FFH ;初始化，所有顯示器、LED滅

　　MOV TMOD,#00010101B ;定時器T1工作于方式1，定時器0工作方式1 MOV TH1,#HIGH(65536-4000)

　　MOV TL1,#LOW(65536-4000)

　　SETB TR1

　　SETB ET1 ;開定時器1中斷

　　SETB EA

　　LOOP: JNB SpCalc,LOOP ;如果未要求計算，轉本身循環(huán)

　　;標號：ＭＵＬＤ功能：雙字節(jié)二進制無符號數乘法

　　;入口條件：被乘數在R2、R3中，乘數在R6、R7中。

　　;出口信息：乘積在R2、R3、R4、R5中。

　　;影響資源：PSW、A、B、R2～R7堆棧需求：２字節(jié)

　　MOV R2,SpCoun

　　MOV R3,SpCoun+1

　　MOV R6,#0

　　MOV R7,#5 ;測得的數值是每秒計數值，轉為每分轉速（每一轉測12次，故乘5而非60）

　　CALL MULD

　　;標號：ＨＢ２功能：雙字節(jié)十六進制整數轉換成雙字節(jié)ＢＣＤ碼整數

　　;入口條件：待轉換的雙字節(jié)十六進制整數在R6、R7中。

　　;出口信息：轉換后的三字節(jié)ＢＣＤ碼整數在R3、R4、R5中。

　　;影響資源：PSW、A、R2～R7堆棧需求：２字節(jié)

　　MOV A,R4

　　MOV R6,A

　　MOV A,R5

　　MOV R7,A ;將乘得的結果送R6R準備轉換，這里結果不可能超過2字節(jié)

　　CALL HB2

　　CBCD:

　　MOV DISPBUF,R3 ;最高位

　　MOV A,R4 ;

　　ANL A,#0F0H ;去掉低4位

　　SWAP A ;將高4位切換到低4位

　　MOV DISPBUF+1,A

　　MOV A,R4

　　ANL A,#0FH

　　MOV DISPBUF+2,A

　　MOV A,R5

　　ANL A,#0F0H

　　SWAP A

　　MOV DISPBUF+3,A

　　MOV A,R5

　　ANL A,#0FH

　　MOV DISPBUF+4,A

　　CLR SpCalc ;清計算標志

　　JMP LOOP

　　;主程序到此結束

　　TIMER1: PUSH ACC;ACC入棧

　　PUSH PSW ;PSW入棧

　　SETB RS0 ;工作區(qū)1

　　JNB TR0,SETTR0 ;如果T0未運行，則開啟T0

　　JMP GO1

　　SETTR0:

　　SETB TR0

　　GO1:

　　INC SecCoun ;秒計數器加1

　　MOV A,SecCoun

　　CJNE A,#251,Go2 ;如果未到1s則轉

　　CLR TR0 ;1ｓ到了，則停止T0的運行

　　MOV SpCoun,TH0

　　MOV SpCoun+1,TL0 ;讀取計數值

　　CLR A

　　MOV TH0,A

　　MOV TL0,A ;清計數器

　　SETB SpCalc ;要求主程序計算速度

　　MOV SecCoun,#0 ;清秒計數器

　　Go2:

　　INC COUNT;用于顯示的計數器

　　MOV A,COUNT

　　CLR C

　　SUBB A,#6

　　JZ N1

　　JMP N2

　　N1: MOV COUNT,#0

　　N2: MOV A,#DISPBUF

　　ADD A,COUNT

　　MOV R0,A ;指向當前要顯示的顯示緩沖區(qū)

　　MOV A,@R0 ;取第一個待顯示數

　　MOV DPTR,#DISPTAB ;字形表首地址

　　MOVC A,@A+DPTR ;取字形碼

　　MOV P0,A ;將字形碼送P0位（段口）

　　MOV A,COUNT

　　MOV DPTR,#BitTab ;字位表首地址

　　MOVC A,@A+DPTR

　　ORL P2,#11111100B

　　ANL P2,A

　　MOV TH1,#HIGH(65536-4000)

　　MOV TL1,#LOW(65536-4000)

　　POP PSW

　　POP ACC

　　RETI

　　BitTab: DB7Fh,0BFH,0DFH,0EFH,0F7H,0FBH

　　DISPTAB:DB0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,88H,83H,0C6H,0A1H,86H,8EH,0FFH

　　……其他數學運算程序（略）

　　四、程序分析

　　主程序在對定時器、計數器、堆棧等進行初始化后即判斷標志SpCalc是否為1，如果為1，說明要求對數據進行計算處理，首先將SpCalc標志清零，以保證下次能正常判斷，然后進入數據處理程序，由于這里的閘門時間為1s，而顯示要求為轉/分，因此，要將測到的數據進行轉換，轉換的方法是將測得的數據乘以60，但由于轉軸上安裝有12只磁鋼，每旋轉一周可以得到12個脈沖，因此，要將測得的數據除以12，所以綜合起來，將測得的數據乘以5即可得到每分鐘的轉速。計算得到的結果是二進制的整數，要將數據送往顯示緩沖區(qū)需要將該數轉化為BCD碼。運算得到的是壓縮BCD碼，需要將其轉換為非壓縮BCD碼，從標號CBCD開始的一段程序即作了這樣的處理。需要說明的是，這里多位二進制乘法和多位二進制到BCD碼的轉換都是用了現(xiàn)成的成熟子程序，因此，首先將二進制數轉換為壓結合實際BCD碼，然后再轉換成非壓縮BCD碼，看似多寫了些程序，實際上這對于保證程序的質量很有好處。

　　定時器T1用作4ms定時發(fā)生器，在定時中斷程序中進行數碼管的動態(tài)掃描，同時產生1s的閘門信號。1s閘門信號的產生是通過一個計數器Count，每次中斷時間為4ms，每計250次即為1s，到了1s后，即清除計數器Count，然后關閉作為計數器用的T0，讀出TH0、TL0中的數值，分別送入SpCoun和SpCoun+1單元，將T0中的值清空，置SpCalc標志為1，要求主程序進行速度值的計算。這里還有一個細節(jié)，用作1s閘門信號產生的Count每次中斷都會加1，而T0卻有一個周期是被關閉的，因此，計數值是251而不是250。

　　看完這一部份內容以后，請讀者自行完成以下工作：

　　1.試用測脈寬法測試速度（提示：80C51單片機內部有高精度信號源，而其計數器又具有門控特性），注意硬件設計要略作更改。

　　2.查找等精度測量原理，試設計等精度測量的硬件設計并編寫相應軟件。